Erlang：这可以在没有列表的情况下完成：反向吗？

我是初学者,学习Erlang.在阅读了Erlang中的列表推导和递归之后,我想尝试实现我自己的map函数,结果如下：

% Map: Map all elements in a list by a function
map(List,Fun) -> map(List,Fun,[]).
map([],_,Acc) -> lists:reverse(Acc);
map([H|T],Fun,Acc) -> map(T,Fun,[Fun(H)|Acc]).

我的问题是：通过递归函数构建列表感觉是错误的,然后在最后反转它.有没有办法按正确的顺序建立列表,所以我们不需要反过来？

中构建的(查看链接中的图片).

在像Erlang列表这样的单链表中,前置元素(或短列表)非常便宜.这是List = [H | T]构造所做的.

反转由cons单元格组成的单链表是非常快的,因为你只需要沿着列表进行一次传递,只需将下一个元素添加到已经反转的部分结果中.正如已经提到的,它也在Erlang的C中实现.

也可以通过尾递归函数来实现以相反顺序构建结果,这意味着不构建堆栈并且(仅在旧版本的Erlang中！)因此可以保存一些存储器.

说完这一切： The Eight Myths of Erlang Performance 之一是在尾部递归函数和调用列表中反向构建总是更好：最后反向/ 1.

这是一个没有列表的正文递归版本：reverse / 1这将在12之前的Erlang版本上使用更多内存,但在当前版本中不是这样：

map([H|T], Fun) ->
    [ Fun(H) | map(T,Fun) ];
map([],_) -> [].

这是使用列表推导的地图版本：

map(List, Fun) ->
    [ Fun(X) || X <- List ].

正如你所看到的那样,这很简单,因为map只是列表推导的一部分,所以你可以直接使用list comprehension,不再需要map.

作为一个额外的纯Erlang实现,它显示了如何有效地逆转cons单元列表(在Erlang中它总是更快地调用列表：reverse / 1,因为它在C中,但做同样的事情).

reverse(List) ->
    reverse(List, []).

reverse([H|T], Acc) ->
    reverse(T, [H|Acc]);
reverse([], Acc) ->
    Acc.

如您所见,列表中只有[A | B]操作,将cons单元分开(当模式匹配时)并在执行[H | Acc]时构建new.